Looplex Knowledge Base

Ask

O tube ask determina que um operando apareça na entrevista. Serve para organizar os cards no sumário.

Formato:

<var>.ask()

Parâmetros:

var: Operando a ser enviado ao sumário

Exemplos:

Observação: Quando um operando não é necessariamente utilizado no template, isto é, caso seu uso esteja protegido por uma condição, ele não aparecerá no sumário automaticamente enquanto sua condição de uso não for verdadeira. Neste caso, é possível usar o ask para chamá-lo ao sumário.

Exemplo de uso: A seguir, temos três cards <enderecamento>, |reus| e |autores|, que são chamados ao sumário na ordem em que os asks são operados.

declarations {
    +|reus| : Vector[String] {
        name = "Ré"
    },
    +|autores| : Vector[Struct]  {
        name = "Autor"
        id = [nome]
        fields {
            +[nome] : String {
                name = "Nome do Autor"
            },
            +[genero] : List ("Masculino", "Feminino") {
                name = "Gênero do Autor"
                atomic = true
                help =  "Selecione o gênero do sujeito para que todas as concordâncias sejam feitas corretamente."
            }                   
        }
    },
    struct[STR_Enderecamento] {
        name = "Endereçamento"
        fields {
            +[numero] : String where ("\d\d\d\d\d\d\d-\d\d.\d\d\d\d.\d.\d\d.\d\d\d\d") {
                name = "Número do processo"
                request = "Informe o número do processo" 
            },                  
            +[uf] : List [*Uf] {
                name = "Seção judiciária" 
                request = "Em qual seção judiciária foi ajuizada a ação?"
                atomic = true
            },
            +[comarca] : String {
                name = "Comarca"
                request = "Insira a comarca"
            }
        }
    },
    +<enderecamento> : STR_Enderecamento
}
operations {
    <enderecamento>.ask(),
    |reus|.ask(),
    |autores|.ask(),
    print uppercase(bold("EXCELENTÍSSIMO SENHOR DOUTOR JUIZ DE DIREITO DO JUIZADO ESPECIAL CÍVEL DA COMARCA DE " & <enderecamento.comarca> & "/" & <enderecamento.uf>)) & "\b\b",
    print bold("Processo: " & <enderecamento.numero>) & "\b\b\b\b",
    print |reus| & ", em face de " & |autores| & ", " & |reus|.grammar("apresenta") & " a seguinte CONTESTAÇÃO."
}

Comportamento da plataforma:

Ask-exemplo

Table of Contents (TOC). Com o uso do ask, podemos controlar a ordem em que os cards são dispostos no sumário. O lawtex suporta outra ferramenta de manipulação do sumário denominada Table of Contents (TOC). Os TOCs são branches que dispõem os cards dentro de seções específicas. Considerando o exemplo acima, poderíamos querer separar o card de Endereçamento dos cards de Ré e de Autor. Assim, organizaríamos nossa entrevista da seguinte forma:

Dados do processo
    - Endereçamento
Qualificação das partes 
    - Autor
    - Ré

Esta ferramenta é especialmente útil para templates que tenham questionários mais extensos.

Por um questão de boas práticas, os TOCs são declarados e operados dentro do nó foot. Note que o título da seção corresponde ao nome do branch.

foot {
    declarations {
        branch[TOC_Processo] {
            name = "Dados do processo"
            index = true
            operations {
                <enderecamento>.ask()
            }
        },
        branch[TOC_Partes] {
            name = "Qualificação das partes"
            index = true
            operations {
                |reus|.ask(),
                |autores|.ask()
            }
        }
    }
    operations {
        use TOC_Processo,
        use TOC_Partes
    }
}

Comportamento da plataforma:

Toc-exemplo

Edit this page on GitHub

Looplex Knowledge Base

Ask

Formato:

Parâmetros:

Exemplos:

Extração de Dados Inteligente

On this page