Break document

O tube breakDocument gera uma quebra de documento para a geração de múltiplos PDFs.

Formato:

Copy
breakDocument(nomeDocumento)

Parâmetros:

• nomeDocumento (opcional): É uma String que corresponde ao nome do documento do arquivo anexo que será gerado. Como é um parâmetro opcional, se não for preenchido o PDF gerado terá o mesmo nome do documento gerado pelo template.

Retorno:

Gera uma quebra de página.

Download

O PDF gerado com o breakDocument é um anexo ao documento gerado pelo template. Assim, para realizar o download dos PDFs, deve-se clicar em "Baixar pdf com anexos separados":

Exemplos:

1. Dividir o documento em múltiplos pdfs: Dado um branch que contém o contrato inteiro BRC_Contrato e um branch que contém as operações referentes ao anexo deste contrato BRC_Anexo, deseja-se fazer o download de cada uma dessas partes do documento em arquivos separados. Vejamos:

Copy
operations {
    use BRC_Contrato,
    breakDocument(),
    use BRC_Anexo
}

2. Utilizando o breakDocument para gerar n documentos a partir de um vetor. Podemos utilizar esse tube para agilizar o processo de geração de petições de substabelecimento em massa. Dado um vetor de estrutura |strPeticoes| que contém os dados de cada processo, usamos o branch que printa a petição dentro de um loop que será repetido para cada elemento do vetor |strPeticoes|. O resultado final será um arquivo zipado com todas as petições em arquivos pdf separados, cada um com um nome diferente definido no parâmetro do tube breakDocument.

Copy
declarations {
    +|strPeticoes| : Vector[Struct] {
        fields {
            +[nro_processo] : String,
            +[peticionante] : String,
            +[enderecamento] : String,
            +[uf] : String
        }
    },
    branch[BRC_PeticaoDeSubs] {
        operations {
                print bold("EXCELENTÍSSIMO SENHOR DOUTOR JUIZ DE DIREITO DA " & uppercase(<peticao.enderecamento>) & " - ESTADO " & uppercase(<peticao.uf>)),
                print "\b\b\b\b\b",
                print bold("Execução Fiscal nº " & <peticao.nro_processo>) & "\b\b" & "</p>",
                print bold(uppercase(<peticao.peticionante>)) & ", pessoa jurídica já qualificada nos autos em epígrafe, vem, por seu advogado, à presença de V. Exa., informar a substituição do patrono responsável pela causa e requerer sejam feitas as futuras intimações, em especial as realizadas por meio da Imprensa Oficial, em nome do advogado constante na procuração, sob pena de nulidade." & "\b\b",
                print "Termos em que," & "\b",
                print "pede deferimento."
        }
    }
}
operations {
    foreach(<peticao> IN |strPeticoes|) {
        breakDocument("Petição de subs - " & <peticao.nro_processo>),
        use BRC_PeticaoDeSubs
    }
}

Obs.: Neste caso, ele vai gerar um arquivo .zip com um documento em branco, correspondente ao que seria o documento principal (que não preenchemos), e os anexos serão as petições de substabelecimento.